THPDFPage.UserWidth

THPDFPage

Renvoie la largeur de la page en unités de dessin, soit 1/THotPDF.Resolution de pouce

Syntaxe Delphi :

property UserWidth: Single; // read-only

Syntaxe C++ :

__property float UserWidth = {read=GetUserWidth};

Description

Les coordonnées X, les marges, les tailles de police et les valeurs renvoyées par TextWidth et TextHeight sont en 1/Resolution de pouce. Width conserve la largeur de page en points et accepte des points à l’affectation ; avec une Resolution autre que 72, elle ne correspond donc pas aux coordonnées de dessin. Lisez UserWidth dès que vous comparez ou combinez la largeur de page avec des coordonnées de dessin, par exemple pour repérer le bord de la marge droite, centrer un bloc ou décider quand le contenu doit passer à la page suivante

À la Resolution par défaut de 72, UserWidth égale Width. Une page dimensionnée en réglant Width et Height se dessine en points quelle que soit la Resolution, et UserWidth égale alors Width elle aussi

program RightAlignedText;
{$APPTYPE CONSOLE}
uses
  SysUtils,
  HPDFDoc;

var
  HPDF: THotPDF;
  Text: AnsiString;
  X: Single;

begin
  HPDF:= THotPDF.Create(nil);
  try
    HPDF.FileName:= 'RightAlignedText.pdf';
    HPDF.Resolution:= 144;                    // Coordinates in 1/144 inch
    HPDF.BeginDoc;
    HPDF.CurrentPage.SetFont('Arial', [], 24); // 12 pt
    Text:= 'Right aligned with a one inch margin';
    // UserWidth is 1190 on an A4 page here; Width stays 595 points
    X:= HPDF.CurrentPage.UserWidth- 144- HPDF.CurrentPage.TextWidth(Text);
    HPDF.CurrentPage.TextOut(X, 144, 0, Text);
    HPDF.EndDoc;
  finally
    HPDF.Free;
  end;
end.

Voir aussi : Width, UserHeight, THotPDF.Resolution